How to extract the last word from the last line of a TXT file through a batch script-CodePudding

I am trying to extract the last word from the last line of a txt file.

The result I want is just Cup$2!.

This is what I tried:

@echo off
SetLocal EnableDelayedExpansion
set L=1
for /F "tokens=2 delims=" %%a in (corner.txt) do (
  set line=%%a
  if !L!==7 set Line7=%%a
  set  /a  L=!L! 1
)

echo The word is %Line7%
pause

The result I'm getting is The word is.

What should I edit to get the above result?

CodePudding user response：

Parsing strings in batch files is never ideal but this seems to work:

@echo off
setlocal ENABLEEXTENSIONS DISABLEDELAYEDEXPANSION

echo.line 1 > "%temp%\SO_Test.txt"
echo. >> "%temp%\SO_Test.txt"
echo.foo^&bar!baz hello/world Cup^&2!/Cup$2!>> "%temp%\SO_Test.txt"
goto start


:start
set "line="
for /F "usebackq delims=" %%a in ("%temp%\SO_Test.txt") do @set line=%%a

:word
set "b="
rem Delims is slash, tab, space and the order is important
for /F "tokens=1,* delims=/  " %%A in ("%line%") do (
    set "line=%%A"
    set "b=%%B"
)
if not "%b%" == "" (
    set "line=%b%"
    goto word
)


echo.Last word is "%line%"

CodePudding user response：

Here's a quick example of how you could capture the substring you require, from reading your code, i.e. the last substring on the seventh line:

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
    Set "var="
    For /F UseBackQ^ Skip^=7^ Delims^=^ EOL^= %%G In ("corner.txt") Do Set "var=%%~nxG" & GoTo Next
    If Not Defined var GoTo EndIt

    :Next
    SetLocal EnableDelayedExpansion
        Echo The word is !var!
    EndLocal

    :EndIt
    Echo Press any key to close . . .
    Pause 1>NUL
EndLocal
Exit /B

If however, as your question title and body asks, you want the last substring of the last line, it's a little bit simpler:

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
    Set "var="
    For /F UseBackQ^ Delims^=^ EOL^= %%G In ("corner.txt") Do Set "var=%%~nxG"
    If Not Defined var GoTo EndIt
    SetLocal EnableDelayedExpansion
        Echo The word is !var!
    EndLocal

    :EndIt
    Echo Press any key to close . . .
    Pause 1>NUL
EndLocal
Exit /B

I will not however be explaining any of it, please use the search facility at the top of the page, and the output from the built in help for each of the commands I have used.

CodePudding user response：

Get line count. Then get the value from 7-th word of the last line:

for /f "tokens=3*" %%i in ('find /c /v /n /i"" corner.txt') do set /a v=%%i-1

for /f "tokens=7*" %%a in ('more corner.txt %v%') do set "String="%%b""

P.S. Variable %String% keeps the value framed by double quotes.

CodePudding user response：

You could use this in a batch-file run by cmd on windows.

FOR /F "delims=" %%A IN ('powershell -NoLogo -NoProfile -Command ^
    "((Get-Content -Path .\corner.txt -Last 1) -split '[ /]')[-1]"') DO (SET LINE7=%%A)
ECHO %LINE7%